Print

Please login or register.
1 Hour 1 Day 1 Week 1 Month Forever
Login with username, password and session length

[NikB]

Is it possible to make a Randomizer Mod related plugin that would autiomatically (when a player joins the server) upload files from a certain GitHub repository, save them in a local folder and subsequently use them to change in-game graphics for all the clients? If yes, how do I make it work?

Thanks in advance.

[Lorgan]

uhhh, not really no...

[NikB]

So? I hope it probably means 'Yes'.
What way do I do that?

[Phantom Brave]

GG2 clients are really, really dumb. The only things the server tells them are what's going on in the game and the map itself. You can't change client graphics without changing the clients to understand.

[NikB]

GG2 clients are really, really dumb. The only things the server tells them are what's going on in the game and the map itself. You can't change client graphics without changing the clients to understand.

Didn't know about that... Well, another question then: is there a way to tell the player joining the server that he doesn't have a required version of plugin installed (if he doesn't) and send him somewhere he can download it from?

[Phantom Brave]

Might as well just be running a mod then.

[NikB]

No way to do that with a plugin?

[NikB]

Please, help! I really have no opportunity to make a mod, but I still need to synchronize my GitHub repository with the plugin.

[Lorgan]

It really is impossible without modifying both the server AND the client. And there is currently no way for the server to make a client download a plugin either.

[NikB]

It really is impossible without modifying both the server AND the client. And there is currently no way for the server to make a client download a plugin either.

That's not great at all, but thanks anyway. Can I ask just one more question?

Let's say you already have a plugin installed. Is it possible to check (when you currently start your RM) whether do you have the latest version of the plugin or there are some available updates?

[Lorgan]

yeah a plugin could do that i'm pretty sure

edit: actually randomizer only loads the plugins when you open the host menu to prevent stupid people from trying to use vanilla plugins and then complain because they won't work. So it is possible but the client needs to have the plugin and open the host menu every time he loads gg2

[NikB]

Thanks. Could you please give me an example on how to make it work?
Or just please help me understand the basics.

[Lorgan]

I made an example plugin:

(click to show/hide)

Code: [Select]

//auto updating plugin
global.curVersion = 1;

global.versionChecker = object_add()
object_set_persistent(global.versionChecker,true);

object_event_add(global.versionChecker,ev_create,0,'
    checkVersion = true;
    host = "dl.dropbox.com";
    path = "/u/61252990/TestPluginVersion.txt";
    event_user(0);
');

object_event_add(global.versionChecker,ev_other,ev_user0,'
    socket = noone;
    update = false;
    
    // downloads a text file off the internet, and parses it for instructions
    // from the developers
    // If any are found, they will be shown/executed/whatever
    
    var CRLF;
    CRLF = chr(13) + chr(10);
    
    socket = tcp_connect(host, 80);
    response = "";
    
    // Send HTTP Request (HTTP 1.0, so we can just read until the server closes the connection)
    write_string(socket, "GET " + path + " HTTP/1.0" + CRLF);
    write_string(socket, "Host: " + host + CRLF + CRLF);
    socket_send(socket);
');

object_event_add(global.versionChecker,ev_step,ev_step_normal,'
    response += read_string(socket, tcp_receive_available(socket));
    
    if(tcp_eof(socket)) {
        if(socket_has_error(socket)) {
            instance_destroy();
            exit;
        }
        
        // Process the received file
        var CRLF, LF, CR;
        CR = chr(13);
        LF = chr(10);
        CRLF = CR + LF;
        
        // find where the header ends, so we can chop it off
        // and just return the important stuff
        var headerlength;
        headerlength = string_pos(CRLF + CRLF, response) + 2 * string_length(CRLF);
        if(headerlength == 0) {
            instance_destroy()
            exit;
        } else {
            response = string_copy(response, headerlength, string_length(response) - headerlength + 1);
            if checkVersion {
                if real(response) > global.curVersion {
                    global.curVersion = real(response);
                    checkVersion = false;
                    show_message("A new version (v"+response+") of testplugin will now be downloaded");
                    host = "dl.dropbox.com";
                    path = "/u/61252990/TestPlugin_"+response+".gml";
                    event_user(0);
                } else instance_destroy();
            } else {
                var file;
                file = file_text_open_write("Plugins/Testplugin_"+string(global.curVersion));
                file_text_write_string(file,response);
                file_text_close(file);
                instance_destroy();
            }
        }
    }
');

object_event_add(MainMenuController,ev_create,0,"instance_create(0,0,global.versionChecker)");


It's linked to my dropbox (but it could also work with github stuff i guess)
First it downloads the current version number from TestPluginVersion.txt (it's just a textfile with the number in it)
If the version is higher it will download the new version (it can currently only download textfiles so no images and stuff)
This testplugin doesn't remove the old file when it updated and it doesn't restart gg2 when the new version is downloaded so you would have to add that too if you were to use this. Also i made this for vanilla gg2 where the plugins get loaded at startup, in randomizer you can just create the object directly in the plugin i guess.

[NikB]

Thanks a lot! Will keep setting everything up.

[NikB]

Sorry again.

Are there actually any peculiar properties related to using a GitHub repositry for getting some information from a certain file?
I just can't link my plugin to it for some reason (DropBox works though)...